/*      $OpenBSD: memmove.S,v 1.8 2022/12/04 08:22:13 tb Exp $  */

/*-
 * Copyright (c) 1993, 1994, 1995 Charles M. Hannum.  All rights reserved.
 * Copyright (c) 1990 The Regents of the University of California.
 * All rights reserved.
 *
 * This code is derived from software contributed to Berkeley by
 * William Jolitz.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 * 3. Neither the name of the University nor the names of its contributors
 *    may be used to endorse or promote products derived from this software
 *    without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 * SUCH DAMAGE.
 */

#include "DEFS.h"

/*
 * Emulate bcopy() by swapping the first two arguments, and jumping
 * into memmove(), which handles overlapping regions.
 */
ENTRY_NB(bcopy)
        pushl   %esi
        pushl   %edi
        movl    12(%esp),%esi
        movl    16(%esp),%edi
        jmp     docopy

/*
 * memmove(caddr_t dst, caddr_t src, size_t len);
 * Copy len bytes, coping with overlapping space.
 */
ENTRY(memmove)
        pushl   %esi
        pushl   %edi
        movl    12(%esp),%edi
        movl    16(%esp),%esi
docopy:
        movl    20(%esp),%ecx
        movl    %edi,%eax
        subl    %esi,%eax
        cmpl    %ecx,%eax               # overlapping?
        jb      1f
#ifdef memcpy_in_asm
        jmp     docopyf                 # nope

/*
 * memcpy() doesn't worry about overlap and always copies forward
 */
ENTRY(memcpy)
        pushl   %esi
        pushl   %edi
        movl    12(%esp),%edi
        movl    16(%esp),%esi
        movl    20(%esp),%ecx
docopyf:
#endif
        movl    %edi,%eax               # setup return value for memcpy/memmove
        shrl    $2,%ecx                 # copy by 32-bit words
        rep
        movsl
        movl    20(%esp),%ecx
        andl    $3,%ecx                 # any bytes left?
        rep
        movsb
        popl    %edi
        popl    %esi
        ret

        _ALIGN_TEXT
1:      movl    %edi,%eax               # setup return value for memmove
        addl    %ecx,%edi               # copy backward
        addl    %ecx,%esi
        std
        andl    $3,%ecx                 # any fractional bytes?
        decl    %edi
        decl    %esi
        rep
        movsb
        movl    20(%esp),%ecx           # copy remainder by 32-bit words
        shrl    $2,%ecx
        subl    $3,%esi
        subl    $3,%edi
        rep
        movsl
        popl    %edi
        popl    %esi
        cld
        ret
#ifdef memcpy_in_asm
END_BUILTIN(memcpy)
#endif
END_BUILTIN(memmove)
END_WEAK(bcopy)