/*      $NetBSD: swapcontext.S,v 1.3 2015/03/27 23:23:14 matt Exp $     */

/*-
 * Copyright (c) 2001 The NetBSD Foundation, Inc.
 * All rights reserved.
 *
 * This code is derived from software contributed to The NetBSD Foundation
 * by Klaus Klein.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
 * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
 * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
 * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
 * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
 * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
 * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
 * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
 * POSSIBILITY OF SUCH DAMAGE.
 */

#include "SYS.h"
#include "assym.h"

__RCSID("$NetBSD: swapcontext.S,v 1.3 2015/03/27 23:23:14 matt Exp $")

#define CALLFRAME_UCP   CALLFRAME_S1
#define CALLFRAME_OUCP  CALLFRAME_S0

ENTRY(swapcontext)
        addi    sp, sp, -CALLFRAME_SIZ          # adjust stack
        REG_S   ra, CALLFRAME_RA(sp)            # save return address
        REG_S   a0, CALLFRAME_OUCP(sp)          # save oucp
        REG_S   a1, CALLFRAME_UCP(sp)           # save ucp

        call    PLT(_C_LABEL(_getcontext))      # getcontext(oucp)
        mv      t0, a0                          # save return value

        REG_L   ra, CALLFRAME_RA(sp)            # restore return address
        REG_L   a0, CALLFRAME_UCP(sp)           # load ucp
        REG_L   a1, CALLFRAME_OUCP(sp)          # load oucp for adjustment
        addi    sp, sp, CALLFRAME_SIZ           # restore stack

        bnez    t0, 1f                          # error? yes, cleanup

        REG_S   ra, UC_GREGS_PC(a1)             # pc <- ra
        REG_S   sp, UC_GREGS_SP(a1)             # adjust sp

        tail    PLT(_C_LABEL(setcontext))       # setcontext(ucp)

1:      ret                                     # simply return
END(swapcontext)